#
# Install library
#

install(
    FILES ${LIBWEBRTC_LIBRARY_PATH}
    DESTINATION ${LIBWEBRTC_INSTALL_LIB_DIR}
    COMPONENT Libraries
)

#
# Install headers
#

install(
    DIRECTORY ${CMAKE_BINARY_DIR}/src/webrtc
    DESTINATION ${LIBWEBRTC_INSTALL_INCLUDE_DIR}
    FILES_MATCHING PATTERN "*.h"
)

#
# Create package
#

set(CPACK_PACKAGE_NAME "${LIBWEBRTC_MAJOR_VERSION}")
set(CPACK_PACKAGE_VERSION_MAJOR "${LIBWEBRTC_MAJOR_VERSION}")
set(CPACK_PACKAGE_VERSION_MINOR "${LIBWEBRTC_MINOR_VERSION}")
set(CPACK_PACKAGE_VERSION_PATCH "${LIBWEBRTC_PATCH_VERSION}")

if (WIN)
  set(CPACK_GENERATOR "ZIP")
else (WIN)
  set(CPACK_GENERATOR "TGZ")
endif (WIN)

if (CMAKE_SYSTEM_NAME MATCHES "Linux")
  set(LIBWEBRTC_PLATFORM "linux")
elseif (CMAKE_SYSTEM_NAME MATCHES "Darwin")
  set(LIBWEBRTC_PLATFORM "mac")
elseif (CMAKE_SYSTEM_NAME MATCHES "Windows")
  set(LIBWEBRTC_PLATFORM "win32")
endif ()

if (CMAKE_SYSTEM_PROCESSOR MATCHES "^arm")
  set(LIBWEBRTC_ARCH "arm")
elseif (CMAKE_SYSTEM_PROCESSOR MATCHES "^i.86$")
  set(LIBWEBRTC_ARCH "x86")
elseif (CMAKE_SYSTEM_PROCESSOR MATCHES "^x86.64$")
  set(LIBWEBRTC_ARCH "x64")
elseif (CMAKE_SYSTEM_PROCESSOR STREQUAL "powerpc")
  set(LIBWEBRTC_ARCH "ppc")
elseif (CMAKE_SYSTEM_PROCESSOR STREQUAL "powerpc64")
  set(LIBWEBRTC_ARCH "ppc64")
else ()
  set(LIBWEBRTC_ARCH "${CMAKE_SYSTEM_PROCESSOR}")
endif ()

set(CPACK_INCLUDE_TOPLEVEL_DIRECTORY 0)
set(CPACK_PACKAGE_FILE_NAME "libwebrtc-${LIBWEBRTC_VERSION}-${LIBWEBRTC_PLATFORM}-${LIBWEBRTC_ARCH}")
set(CPACK_PACKAGE_INSTALL_DIRECTORY "libwebrtc")

include(CPack)